Arch Linux

jarryson

会员

注册时间： 2012-08-22

帖子： 15

推荐一个播放器Snappy

一个还在开发，但是小巧，全新特性的播放器。特点：控制栏嵌入在播放画面中。

主页：http://projects.gnome.org/snappy/

AUR里面有PKGBUILD，不过版本并不是最新，有比较严重的不稳定的bug。最新版是0.3.7

PKGBUILD:

pkgname=snappy-player
_pkgname=snappy
pkgver=0.3.7
pkgrel=1
pkgdesc="Media player with minimalistic interface"
arch=('x86_64')
url="http://projects.gnome.org/snappy/"
license=('GPL')
depends=(clutter-gst clutter-gtk libxtst desktop-file-utils hicolor-icon-theme)
makedepends=(gnome-common)
source=(https://git.gnome.org/browse/snappy/snapshot/$_pkgname-$pkgver.tar.gz)
install=snappy-player.install
md5sums=('SKIP')

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  sed -i "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" configure.ac
  sed -i "s/Exec=snappy/Exec=snappy-player/" data/snappy.desktop
  ./autogen.sh --prefix=/usr
  make
}

check() {
  cd "$srcdir/$_pkgname-$pkgver"
  make -k check
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  mv $pkgdir/usr/bin/snappy{,-player}
  mv $pkgdir/usr/share/applications/snappy{,-player}.desktop
}

snappy-player.install

post_install() {
    gtk-update-icon-cache -q -f /usr/share/icons/hicolor
    update-desktop-database -q
}

post_upgrade() {
    post_install
}

post_remove() {
    post_install
}

xgdgscarch

会员

注册时间： 2012-05-07

帖子： 191

Re: 推荐一个播放器Snappy

就这个特性啊，smplayer按ctrl+c就行。

jarryson

会员

注册时间： 2012-08-22

帖子： 15

Re: 推荐一个播放器Snappy

那样只是隐藏控制栏，totem，gnome-mplayer都可以。这个是覆盖在画面上的

xgdgscarch

会员

注册时间： 2012-05-07

帖子： 191

Re: 推荐一个播放器Snappy

那样只是隐藏控制栏，totem，gnome-mplayer都可以。这个是覆盖在画面上的

可能是smplayer选项里interface->Floating Control->Display in compact mode too默认没打开，打开效果就跟这个差不多了，只不过没透明而已。