[已解决]如何添加Brother DCP-B7530DN打印机

Luke Croft · 2021-03-06 19:46:44

GNOME已安装并启用CUPS服务，打印机通过网络连接，打印机型号：Brother DCP-B7530DN，能够发现打印机，但无法连接，请教该如何解决？谢谢！

套用AUR里brother-dcp-b7520dw的PKGBUILD：

pkgname=brother-dcp-b7530dn
pkgver=4.0.0
pkgrel=1
pkgdesc="LPR and CUPS driver for the Brother DCP-B7530DN printer"
arch=("i686" "x86_64")
url="https://support.brother.com/g/b/producttop.aspx?c=cn&lang=zh&prod=dcpb7530dn_cn"
license=("EULA")
groups=("base-devel")
source=("https://www.brother.cn/project/d2/201911/dcpb7530dnpdrv-4.0.0-1.i386.rpm")
md5sums=('642d3d39f500d83f6485cb096392a8e6')

package() {
  # This package is based off of the brother-mfc-l2710dw package due to the identical packaging. All credit should go to enginefeeder101 for the script.

	_model="DCPB7530DN"

  # using /usr/share instead of /opt
  mkdir -p "$pkgdir/usr/share"
  cp -R "$srcdir/opt/brother" "$pkgdir/usr/share"
  sed -i 's|\\\/opt\\\/|\\\/usr\\\/|' "$pkgdir/usr/share/brother/Printers/$_model/cupswrapper/lpdwrapper"
  sed -i 's|\\\/opt\\\/|\\\/usr\\\/|' "$pkgdir/usr/share/brother/Printers/$_model/lpd/lpdfilter"

  # /etc/printcap is managed by cups
  find "$pkgdir" -type f -name 'setupPrintcap*' -delete

  # symlink for lpdwrapper so it correctly figures out the printer model from the path
  install -d "$pkgdir/usr/lib/cups/filter/"
  ln -s "/usr/share/brother/Printers/$_model/cupswrapper/lpdwrapper" "$pkgdir/usr/lib/cups/filter/brother_lpdwrapper_$_model"

  # symlink for the PPD
  install -d "$pkgdir/usr/share/cups/model/"
  ln -s "/usr/share/brother/Printers/$_model/cupswrapper/brother-$_model-cups-en.ppd" "$pkgdir/usr/share/cups/model/"

  # a couple architecture-specific symlinks
  ln -s "/usr/share/brother/Printers/$_model/lpd/$CARCH/brprintconflsr3" "$pkgdir/usr/share/brother/Printers/$_model/lpd/"
  ln -s "/usr/share/brother/Printers/$_model/lpd/$CARCH/rawtobr3" "$pkgdir/usr/share/brother/Printers/$_model/lpd/"

  # symlink for inf because it tries to execute it there
  ln -s "/usr/share/brother/Printers/$_model/inf" "$pkgdir/usr/share/brother/Printers/$_model/lpd/"
}

makepkg后安装驱动，直接在CUPS管理页面里添加打印机，此处需要选择LPD/LPR 主机或打印机这一项，Connection里直接使用IP地址的形式输入“lpd://对应打印机的IP地址/queue”，然后根据提示输入名字选好驱动之类的就大功告成了！

最近编辑记录 Luke Croft (2021-03-14 13:24:42)

twobooks · 2021-03-07 00:41:58

我用的是Brother MFC-7860DW, 下载AUR中的snapshot, 安装以后可以通过网络添加打印机, 但是所有的打印job都被无视, 最后删除打印机, 通过USB添加打印机

Luke Croft · 2021-03-12 22:09:15

不具备把网络打印机接到USB上的条件

twobooks 说：

我用的是Brother MFC-7860DW, 下载AUR中的snapshot, 安装以后可以通过网络添加打印机, 但是所有的打印job都被无视, 最后删除打印机, 通过USB添加打印机

Luke Croft · 2021-03-14 13:23:36

直接在CUPS管理页面里添加打印机，选择LPD/LPR 主机或打印机这一项，Connection里直接使用IP地址的形式输入“lpd://对应打印机的IP地址/queue”，不要用他自动生成的连接地址，我开始也是添加上了，但打印机没反应，改成IP就好了。

twobooks 说：

我用的是Brother MFC-7860DW, 下载AUR中的snapshot, 安装以后可以通过网络添加打印机, 但是所有的打印job都被无视, 最后删除打印机, 通过USB添加打印机

Arch Linux

#1 2021-03-06 19:46:44

[已解决]如何添加Brother DCP-B7530DN打印机

#2 2021-03-07 00:41:58

Re: [已解决]如何添加Brother DCP-B7530DN打印机

#3 2021-03-12 22:09:15

Re: [已解决]如何添加Brother DCP-B7530DN打印机

#4 2021-03-14 13:23:36

Re: [已解决]如何添加Brother DCP-B7530DN打印机

页脚